케이턱에서 많은 도움을 받고 있는 엔드유저입니다.

사소한 것이지만 나름대로 뿌듯해서 올려봅니다.

시간과 정성을 들여 해결책을 주시는 모든 분들게 감사드립니다. 

verbatimtex

\input kotexutf.tex

etex;

beginfig(1)

numeric u, ang; path p,q,s; u := 30mm;

vardef arcsind primary x = angle((sqrt(1-x*x),x)) enddef;

ang := arcsind(2/sqrt(13)); %approximately 33.69;

fill fullcircle scaled u withcolor blue;

%1 태극기 바탕 가로 : 세로 = 3 : 2

draw ((-1.5,-1)--(1.5,-1)--(1.5,1)--(-1.5,1)--cycle)scaled u;

%2 태극

p = ((-0.5,0){down}..{up}(0,0){up}..

{down}(0.5,0){up}..(0,0.5){left}..cycle) scaled u;

fill p rotated -ang withcolor red;

fill p rotated -(ang+180) withcolor blue;

%3 긴 괘 그리기

q = ((3/4, 1/4)--(3/4, -1/4)--(5/6, -1/4)--(5/6, 1/4)--cycle)

scaled u;

for i=ang, (180-ang), (180+ang), (360-ang):

fill q rotated i withcolor black;

fill q shifted (1/8u, 0) rotated i withcolor black;

fill q shifted (1/4u, 0) rotated i withcolor black;

endfor;

%4 짧은 괘 만들기

s = ((3/4, 1/48)--(3/4, -1/48)--(5/6, -1/48)--(5/6, 1/48)--cycle)

scaled u;

unfill s rotated ang;

unfill s rotated -ang;

unfill s shifted (1/8u,0) rotated (180+ang);

unfill s shifted (1/8u,0) rotated (360-ang);

unfill s shifted (1/4u,0) rotated ang;

unfill s shifted (1/4u,0) rotated (360-ang);

endfig;end%-------------------------------------------